repo-ng

Repo Command

=============================

For insertion, deletion and other operations of repo, these commands are encoded in the form of [[ndn-cxx:SignedInterest|Signed Interests]]:

    /<repo-prefix>/<command-verb>/................./.........................................

                                  \______  _______/ \__________________  ___________________/

                                         \/                            \/

                                 RepoCommandParameter   Signed Interest additional components

The semantics of repo command interest is as follows:

The name semantics is defined to have following components:

* ``<repo prefix>`` refers to specific prefix repo is listening

* ``<command verb>`` refers to the name of command

* ``<RepoCommandParameter>`` refers to parameters of repo command

The following components are components of singed interest for access control:

* ``<timestamp>``

* ``<random-value>``

* ``<SignatureInfo>``

* ``<SignatureValue>``

For prefix of repo /ucla/cs/repo/, the command will be defined as this:

    /ucla/cs/repo/<command verb>/<RepoCommandParameter>/<timestamp>/<random-value>/<SignatureInfo>/<SignatureValue>

### RepoCommandParameter

    RepoCommandParameter ::= REPOCOMMANDPARAMETER-TYPE TLV-LENGTH

                               Name?

                               StartBlockId?

                               EndBlockId?

                               ProcessId?

                               MaxInterestNum?

                               WatchTimeout?

                               WatchStatus?

                               InterestLifetime?

    Name                  ::= NAME-TYPE TLV-LENGTH NameComponent*

    NameComponent         ::= NAME-COMPONENT-TYPE TLV-LENGTH BYTE+

    StartBlockId          ::= STARTBLOCKID-TYPE TLV-LENGTH

                               nonNegativeInteger

    EndBlockId            ::= ENDBLOCKID-TYPE TLV-LENGTH

                               nonNegativeInteger

    ProcessId             ::= PROCESSID-TYPE TLV-LENGTH

                               nonNegativeInteger

    MaxInterestNum        ::= MAX-INTEREST-NUM-TYPE TLV-LENGTH

                               nonNegativeInteger

    WatchTimeout          ::= WATCH-TIMEOUT-TYPE TLV-LENGTH

                               nonNegativeInteger

    WatchStatus           ::= WATCH-STATUS-TYPE TLV-LENGTH

                               nonNegativeInteger

    InterestLifetime      ::= INTEREST-LIFETIME-TYPE TLV-LENGTH

                               nonNegativeInteger

#### Repo Command Selectors

Repo command supports parts of interest selectors of interest to indicate which contents to process. The definition of standard NDN selectors is described in [NDN Selectors Doc](http://named-data.net/doc/ndn-tlv/interest.html#selectors). The concrete definitions of both standard NDN selectors and repo command selectors are the same.

The difference between standard NDN interest and Repo Deletion Command interest is that, the standard NDN selectors just matches **one** data packet that conforms to the selector conditions, but repo command selectors would matches **any** data packets. For example, if Interest is expressed for /ndn/edu and Exclude specifies one name component ucla, in standard NDN interest, the data producers will first include all the data packets with prefix /ndn/edu but not /ndn/edu/ucla, and then just selects one data packet. In repo deletion command interest, it will select all the data packets with prefix /ndn/edu but not /ndn/edu/ucla. However, in repo insert command, the repo will fetch one data just like standard interest selectors.

Repo command supports parts of standard NDN interests including MinSuffixComponents, MaxSuffixComponents, PublisherPublicKeyLocator, and Exclude. ChildSelector is supported in insertion command but not deletion command. If command contains other selectors, repo will ignore these not supported selectors. In addition, selectors are just supported in delete command. If other commands contains selectors, repo will ignore selectors when processing these commands.

The form of selectors is as follows:

    Selectors             ::= SELECTORS-TYPE TLV-LENGTH

                               MinSuffixComponents?

                               MaxSuffixComponents?

                               PublisherPublicKeyLocator?

                               Exclude?

                               ChildSelector?

    MinSuffixComponents   ::= MIN-SUFFIX-COMPONENTS-TYPE TLV-LENGTH

                               nonNegativeInteger

    MaxSuffixComponents   ::= MAX-SUFFIX-COMPONENTS-TYPE TLV-LENGTH

                               nonNegativeInteger

    PublisherPublicKeyLocator ::= KeyLocator

    Exclude               ::= EXCLUDE-TYPE TLV-LENGTH Any? (NameComponent (Any)?)+

    Any                   ::= ANY-TYPE TLV-LENGTH(=0)

    ChildSelector         ::= CHILD-SELECTOR-TYPE TLV-LENGTH

                               nonNegativeInteger

#### StartBlockId, EndBlockId

StartBlockId and EndBlockId are used to process segmented data. StartBlockId indicate the first segment number and EndBlockId indicate the last segment number. Repo will process segment data whose segment id between StartBlockId and EndBlockId. If StartBlockId is missing, the first segment id the repo process is 0; If EndBlockId is missing, this scenario is described in specific process in Repo Insertion Command section and Repo Deletion Command section.

#### Conflict of Selectors and StartBlockId, EndBlockId

Repo cannot process command with both selectors and StartBlockId, EndBlockId in RepoCommandParameter. If the RepoCommandParameter carries both, repo will ignore this command interest and return with error code of 405.

#### ProcessId

ProcessId is used by insertion and deletion check command to indicate specific insertion and deletion process. The ProcessId is fetched by repo command response of insertion and deletion command.

#### InterestLifetime

InterestLifetime is the maximum latency between interest sent and data received. If no data received after the InterestLifetime, the interest will time out. InterestLifetime is optional and a default value will be set if it is not specified.

#### MaxInterestNum

MaxInterestNum is used by watched prefix insertion protocol to set the upper limit of the total number of interests to be sent.

#### WatchTimeout

WatchTimeout is used by watched prefix insertion protocol to set the time duration of the whole watching process.

#### WatchStatus

WatchStatus is used by watched prefix insertion protocol to indicate the status of watching process. If the WatchStatus is true, then the watching prefix is running, otherwise, it is not.

## Repo Command Response

Repo command response is the response data packet of repo command interest. The response contains statuscode to indicate the status of command process and other information. A TLV-encoded block called ``RepoCommandResponse`` is encoded in content of the data packet.

    RepoCommandResponse   ::= INSERTSTATUS-TYPE TLV-LENGTH

                               ProcessId?

                               StatusCode

                               StartBlockId?

                               EndBlockId?

                               InsertNum?

                               DeleteNum?

    ProcessId            ::= PROCESSID-TYPE TLV-LENGTH

                                nonNegativeInteger 

    StatusCode            ::= STATUSCODE-TYPE TLV-LENGTH

                                nonNegativeInteger    

    StartBlockId          ::= STARTBLOCKID-TYPE TLV-LENGTH

                                nonNegativeInteger

    EndBlockId            ::= ENDBLOCKID-TYPE TLV-LENGTH

                                nonNegativeInteger

    InsertNum             ::= INSERTNUM-TYPE TLV-LENGTH

                                nonNegativeInteger

    DeleteNum             ::= DELETENUM-TYPE TLV-LENGTH

                                nonNegativeInteger

### Name

Name indicates the Name in repocommandparameter of repo command

### ProcessId

ProcessId is a random number generated by repo to indicate the number of the command process. Client could use this ProcessId to check the status of specific command.

### StatusCode

StatusCode indicates the status of repo command process. The statuscodes of insert and deletion command are described in following insertion and deletion specification.

### StartBlockId, EndBlockId

StartBlockId and EndBlockId are the same as those of RepoCommandParameter. If either of those in RepoCommandParameter is missing, repo will set them as the Id known for now. For example, if StartBlockId is missing in RepoCommandParameter, StartBlockId in response will be set 0. If EndBlockId is missing in RepoCommandParameter, EndBlockId will be set null untill Repo get FinalBlockId in data packet. If FinalBlockId in returned data packet is less than EndBlockId, the EndBlockId will be set FinalBlockId.

### InsertNum, DeleteNum

InsertNum is used in reponse of insertion status check to indicate how many data packets have been successfully inserted into the repo. DeleteNum is used in response of deletion command and deletion check command. DeleteNum indicates how many data packets have been successfully deleted from repo.

## Repo TLV Type Encoding Number

Type                  | Number

----------------------| -------

RepoCommandParameter  | 201

StartBlockId          | 204

EndBlockId            | 205

ProcessId             | 206

RepoCommandResponse   | 207

StatusCode            | 208

InsertNum             | 209

DeleteNum             | 210

MaxInterestNum        | 211

WatchTimeout          | 212

WatchStatus           | 213

InterestLifetime      | 214

## Repo Trust Model

The trust model of repo depends on people who deploy the repo service, such as PKI. Repo can specify their own verification policies, and data consumers can specify their own trust anchors. The NDN [FAQ](http://named-data.net/project/faq/#How_does_NDN8217s_8220trust_management8221_work) shows how NDN trust managment works.